var
   Q:array[1..100] of byte;   {Черга}
   left,right:byte;
procedure Enqueue(x:word); {процедура додавання в чергу вершини}
  begin
    Q[right]:=x;
    if right=100 then right:=1 else inc(right);
  end;
procedure Dequeue;              {процедура видалення з черги вершини}
  begin
    if left=100 then left:=1 else inc(left);
  end;
var
   G:array[1..100,1..100] of word;  {граф}
   i,j,k,h:word;
   d:array[1..100] of word;             {масив відстаней}
   p:array[1..100] of word;             {масив нащадків}
   color:array[1..100] of byte;         {масив кольорів}
   n:word;
   fin:text;
   beg:word;                    {початкова вершина}
begin
   k:=0;
  {зчитування графа з файлу, ім'я котрого - перший параметр командної стрічки}  
   assign(fin,paramstr(1)); reset(fin);
   read(fin,n); readln(fin,beg);
   while not EOF(fin) do
     begin
       read(fin,i); readln(fin,j);
       g[i,j]:=1; g[j,i]:=1;
     end;
   close(fin);
  {кінець зчитування з файла}
  {ініціалізація масивів}
   for i:=1 to n do
     begin
       color[i]:=0;
       d[i]:=65535;
       p[i]:=0;
     end;
  {кінець ініціалізації масивів}
  color[beg]:=1;
  d[beg]:=0;
  p[beg]:=0;
  left:=1;
  right:=1;
  Enqueue(beg);             {Додавання першої вершини в чергу}
  while left<>right do      {Поки черга не порожня}
    begin
      k:=Q[left];
      for i:=1 to n do        {для всіх вершин...}
        if g[k,i]=1 then       {...суміжних з k...}
        begin
          if color[i] = 0 then {...якщо ми її ще но обробляли...}
            begin
              color[i]:=1;       {...зробити колір сірим...}
              d[i]:=d[k]+1;    {...вказати відстань...}
              p[i]:=k;             {...вказати нащадка...}
              EnQueue(i);      {...додати в чергу}
            end;
        end;
      Dequeue;                {видалити з черги}
      color[k]:=2;             {зробити колір чорним: вершина повністю оброблена}
    end;
   
  {вивід на екран відстаней від s до всіх вершин, які можна досягнути з неї}
  for i:=1 to n do
    write(d[i],' ');
    writeln;
end.